dev-libs/granite: add granite-0.4.1

dev-libs/granite/Manifest

@@ -0,0 +1,3 @@
+DIST granite-0.4.1.tar.xz 303248 SHA256 8bb411523e6cd5685c928dbfe08893892189cedf9fad5f537aa76182032cf09c SHA512 f07ba2e4dd130b03cf3c0f29cb176bcd5adfb19c02b4cf25c8a11d2ec2ebe178a54f9e2de9300f8075066712b2154a0529498355433f259041aa4e36c662c869 WHIRLPOOL bb854f8c58685c1475d2f19c124a972baeefc87614b9f0f868e2327aa99affeaa1342ca8bcf8551b4c6c2fd47f66e2456ebbdac20d617bdeb9c7a0661d859721
+EBUILD granite-0.4.1.ebuild 1122 SHA256 2b6b961195b39a0e730b5b0e22ad3c03e25d41f3d70ddcd47615aa6872f3bd89 SHA512 99beb55b3326c697052c40a9570b1f988a2c78973adc74ba33ac58067d25a3de344234ea4472472450bd468828e940ce7f5f58af9e5e2e89c4832baa73daa132 WHIRLPOOL 245a5d505ba009e0554b21a7fe1d0aecfdc4151de1e1157ede414584f76fc07bdc82f2b986492a5ae0bbabc2b8cf9fe192b96113fe9fbabab44fcca6e1d60c74
+MISC metadata.xml 214 SHA256 922fd4048dade8049d8a795670d3528355af05c2caf6b808fddce9e569151059 SHA512 bec672c74ddfb91f6939258681767ad87123c2e9c750a2166a101e2a2326619625c92c53a6516e7b4af642194c3b59be1cbe6e952c814768912b9222fc2673a2 WHIRLPOOL 49a0feacecae5648b989013fd730f1b6d9c257d996ae09affa52a66c3a52b6690dd15764b58b88e44f6a2ff01e03b200cc8aad22de0e3ec8dbc694ade3bb7989

dev-libs/granite/granite-0.4.1.ebuild

@@ -0,0 +1,60 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+VALA_MIN_API_VERSION="0.24"
+
+inherit cmake-utils gnome2-utils multilib vala versionator
+
+DESCRIPTION="A development library for elementary development"
+HOMEPAGE="https://launchpad.net/granite"
+SRC_URI="https://launchpad.net/${PN}/$(get_version_component_range 1-2)/${PV}/+download/${P}.tar.xz"
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE=""
+
+RDEPEND="
+	>=dev-libs/glib-2.32:2
+	dev-libs/gobject-introspection:=
+	dev-libs/libgee:0.8[introspection]
+	>=x11-libs/gtk+-3.11.6:3
+"
+DEPEND="${RDEPEND}
+	$(vala_depend)
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+
+DOCS=( AUTHORS )
+
+src_prepare() {
+	vala_src_prepare
+	sed -i -e "/NAMES/s:valac:${VALAC}:" cmake/FindVala.cmake || die
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	mycmakeargs=(
+		-DLIB_INSTALL_DIR=$(get_libdir)
+	)
+	cmake-utils_src_configure
+}
+
+src_install() {
+	HTML_DOCS=( doc/. )
+	cmake-utils_src_install
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}

dev-libs/granite/metadata.xml

@@ -0,0 +1,7 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<upstream>
+		<remote-id type="launchpad">granite</remote-id>
+	</upstream>
+</pkgmetadata>