diff --git a/xfce-base/xfce4-panel/Manifest b/xfce-base/xfce4-panel/Manifest
new file mode 100644
index 0000000..b182638
--- /dev/null
+++ b/xfce-base/xfce4-panel/Manifest
@@ -0,0 +1,3 @@
+DIST xfce4-panel-4.13.3.tar.bz2 1239212 BLAKE2B 8bab0c2f291874064ec8684ab8ada8177cca3f6ad163638bb57b02d0e0f77ed484ecb71bd9a4e54a63d75a572db260d6f92b755d413e1c6c111aef613ca2c2cd SHA512 99921ffc295b0e00689df50946ea326496c6fca68d6dfc6a563c0fb9e18bef1e537659963e3a0e6ee83756417565ac3531bc43e0e909dbb369068e4905bde045
+EBUILD xfce4-panel-4.13.3.ebuild 1332 BLAKE2B b48e1734ad43630418d41dfb853b753e697c75bc851dd404fd48650f42b2d80741da9c21c77d6f241570770487a1d2020969bcc03ebea42549c024f7d3cfa9d2 SHA512 166037ea6a7ba0765286620aeca0164d3ff9498645338783f1397480b62e8e7aa470aa078580bfc837eef1fb7dfc93e58b1319d96065dcaa8d8b66b0d52825da
+MISC metadata.xml 247 BLAKE2B f381ffd75f3fdb2842002ea885015f443cc35334f0420d70a61d6730bd55c11750d6a177831dc7c8564eec4dc3863db6085162e58848b0dceb09799006a1b2c5 SHA512 25494c0053fb7b2ed0f78ecc2de8a8ae08a971db8e15f89e906a1d43177fef53eb9ec5dd075a5c67ddee2be112c0943f6c87e4870d405436bddfea3a4fa19203
diff --git a/xfce-base/xfce4-panel/metadata.xml b/xfce-base/xfce4-panel/metadata.xml
new file mode 100644
index 0000000..359901b
--- /dev/null
+++ b/xfce-base/xfce4-panel/metadata.xml
@@ -0,0 +1,8 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>xfce@gentoo.org</email>
+    <name>XFCE Team</name>
+  </maintainer>
+</pkgmetadata>
diff --git a/xfce-base/xfce4-panel/xfce4-panel-4.13.3.ebuild b/xfce-base/xfce4-panel/xfce4-panel-4.13.3.ebuild
new file mode 100644
index 0000000..14d2d25
--- /dev/null
+++ b/xfce-base/xfce4-panel/xfce4-panel-4.13.3.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit gnome2-utils xdg-utils
+
+DESCRIPTION="Panel for the Xfce desktop environment"
+HOMEPAGE="https://www.xfce.org/projects/"
+SRC_URI="mirror://xfce/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="introspection"
+
+RDEPEND=">=dev-libs/glib-2.24:=
+	>=x11-libs/cairo-1:=
+	>=x11-libs/gtk+-2.20:2=
+	>=x11-libs/gtk+-3.16:3=[introspection?]
+	x11-libs/libX11:=
+	x11-libs/libwnck:3=
+	>=xfce-base/exo-0.11.2:=
+	>=xfce-base/garcon-0.5:=
+	>=xfce-base/libxfce4ui-4.13:=
+	>=xfce-base/libxfce4util-4.13:=[introspection?]
+	>=xfce-base/xfconf-4.13:=
+	introspection? ( dev-libs/gobject-introspection:= )"
+DEPEND="${RDEPEND}
+	dev-lang/perl
+	dev-util/gtk-doc-am
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig"
+
+src_configure() {
+	local myconf=(
+		$(use_enable introspection)
+
+		# enable GTK+2 compatibility
+		--enable-gtk2
+	)
+
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+}